home *** CD-ROM | disk | FTP | other *** search
/ Almathera Ten Pack 3: CDPD 3 / Almathera Ten on Ten - Disc 3: CDPD3.iso / fish / 726-750 / 742 / rkrm_lib3 / rkrm_lib3.lha / Expansion / autoboot.asm next >
Assembly Source File  |  1992-09-03  |  12KB  |  309 lines
  1. *
  2. * Copyright (c) 1992 Commodore-Amiga, Inc.
  3. * 
  4. * This example is provided in electronic form by Commodore-Amiga, Inc. for 
  5. * use with the "Amiga ROM Kernel Reference Manual: Devices", 3rd Edition, 
  6. * published by Addison-Wesley (ISBN 0-201-56775-X).
  7. * 
  8. * The "Amiga ROM Kernel Reference Manual: Devices" contains additional 
  9. * information on the correct usage of the techniques and operating system 
  10. * functions presented in these examples.  The source and executable code 
  11. * of these examples may only be distributed in free electronic form, via 
  12. * bulletin board or as part of a fully non-commercial and freely 
  13. * redistributable diskette.  Both the source and executable code (including 
  14. * comments) must be included, without modification, in any copy.  This 
  15. * example may not be published in printed form or distributed with any
  16. * commercial product.  However, the programming techniques and support
  17. * routines set forth in these examples may be used in the development
  18. * of original executable software products for Commodore Amiga computers.
  19. * 
  20. * All other rights reserved.
  21. * 
  22. * This example is provided "as-is" and is subject to change; no
  23. * warranties are made.  All use is at your own risk. No liability or
  24. * responsibility is assumed.
  25. *
  26. **********************************************************************
  27. *
  28. * Sample autoboot code fragment
  29. *
  30. **********************************************************************
  31.  
  32. **
  33. **
  34. ** These are the calling conventions for the Diag routine
  35. **
  36. ** A7 -- points to at least 2K of stack
  37. ** A6 -- ExecBase
  38. ** A5 -- ExpansionBase
  39. ** A3 -- your board's ConfigDev structure
  40. ** A2 -- Base of diag/init area that was copied
  41. ** A0 -- Base of your board
  42. **
  43. ** Your Diag routine should return a non-zero value in D0 for success.
  44. ** If this value is NULL, then the diag/init area that was copied
  45. ** will be returned to the free memory pool.
  46. **
  47.  
  48.             INCLUDE "exec/types.i"
  49.             INCLUDE "exec/nodes.i"
  50.             INCLUDE "exec/resident.i"
  51.             INCLUDE "libraries/configvars.i"
  52.  
  53.             ; LVO's resolved by linking with library amiga.lib
  54.             XREF   _LVOFindResident
  55.  
  56. ROMINFO     EQU      1
  57. ROMOFFS     EQU     $0
  58.  
  59. * ROMINFO defines whether you want the AUTOCONFIG information in
  60. * the beginning of your ROM (set to 0 if you instead have PALS
  61. * providing the AUTOCONFIG information instead)
  62. *
  63. * ROMOFFS is the offset from your board base where your ROMs appear.
  64. * Your ROMs might appear at offset 0 and contain your AUTOCONFIG
  65. * information in the high nibbles of the first $40 words ($80 bytes).
  66. * Or, your autoconfig ID information may be in a PAL, with your
  67. * ROMs possibly being addressed at some offset (for example $2000)
  68. * from your board base.  This ROMOFFS constant will be used as an
  69. * additional offset from your configured board address when patching 
  70. * structures which require absolute pointers to ROM code or data.
  71.  
  72. *----- We'll store Version and Revision in serial number
  73. VERSION        EQU    37        ; also the high word of serial number
  74. REVISION    EQU    1        ; also the low word of serial number
  75.  
  76. * See the Addison-Wesley Amiga Hardware Manual for more info.
  77.  
  78. MANUF_ID    EQU    2011        ; CBM assigned (2011 for hackers only)
  79. PRODUCT_ID    EQU    1        ; Manufacturer picks product ID
  80.  
  81. BOARDSIZE       EQU     $40000          ; How much address space board decodes
  82. SIZE_FLAG    EQU     3        ; Autoconfig 3-bit flag for BOARDSIZE
  83.                     ;   0=$800000(8meg)  4=$80000(512K)
  84.                     ;   1=$10000(64K)    5=$100000(1meg)
  85.                     ;   2=$20000(128K)   6=$200000(2meg)
  86.                     ;   3=$40000(256K)   7=$400000(4meg)
  87.  
  88.             CODE
  89.  
  90.  
  91. *******  RomStart  ***************************************************
  92. **********************************************************************
  93.  
  94. RomStart:
  95.  
  96.     IFGT    ROMINFO
  97. ;
  98. ;   ExpansionRom structure
  99. ;
  100. ;   Note - If you implement your ExpansionRom and ExpansionControl
  101. ;   with PALS, then you can comment out everything until DiagStart:
  102. ;   (ie. Make ROMID EQU 0)
  103.  
  104. *    ; High nibbles of first two words ($00,$02) are er_Type (not inverted)
  105.                         ; er_Type
  106.         dc.w    $D000            ;   11xx normal board type
  107.                         ;   xx0x not in memory free list
  108.                         ;   xxx1 Diag valid (has driver)
  109.         dc.w    (SIZE_FLAG<<12)&$7000    ;   0xxx not chained
  110.                         ;   xnnn flags board size
  111.  
  112. *    ; High nibbles of next two words are er_Product
  113. *    ; These are inverted (~), as are all other words except $40 and $42
  114.  
  115.                         ; er_Product
  116.         dc.w    (~(PRODUCT_ID<<8))&$f000,(~(PRODUCT_ID<<12))&$f000
  117.  
  118.                         ; er_Flags
  119.         dc.w    (~$C000)&$f000        ;   ~1xxx board is moveable
  120.                         ;   ~x1xx board can't be shut up
  121.         dc.w    (~0)&$f000        ;
  122.  
  123.         dc.w    (~0)&$f000,(~0)&$f000    ; er_Reserved03
  124.  
  125.                         ; er_Manufacturer
  126.         dc.w    (~(MANUF_ID))&$f000,(~(MANUF_ID<<4))&$f000
  127.         dc.w    (~(MANUF_ID<<8))&$f000,(~(MANUF_ID<<12))&$f000
  128.  
  129.                         ; er_SerialNumber
  130.         dc.w    (~(VERSION))&$f000,(~(VERSION<<4))&$f000
  131.         dc.w    (~(VERSION<<8))&$f000,(~(VERSION<<12))&$f000
  132.         dc.w    (~(REVISION))&$f000,(~(REVISION<<4))&$f000
  133.         dc.w    (~(REVISION<<8))&$f000,(~(REVISION<<12))&$f000
  134.  
  135.                         ; er_InitDiagVec
  136.         dc.w    (~((DiagStart-RomStart)))&$f000
  137.         dc.w    (~((DiagStart-RomStart)<<4))&$f000
  138.         dc.w    (~((DiagStart-RomStart)<<8))&$f000
  139.         dc.w    (~((DiagStart-RomStart)<<12))&$f000
  140.  
  141.         dc.w    (~0)&$f000,(~0)&$f000    ; er_Reserved0c
  142.         dc.w    (~0)&$f000,(~0)&$f000    ; er_Reserved0d
  143.         dc.w    (~0)&$f000,(~0)&$f000    ; er_Reserved0e
  144.         dc.w    (~0)&$f000,(~0)&$f000    ; er_Reserved0f
  145.  
  146.     IFNE    *-RomStart-$40
  147.     FAIL    "ExpansionRom structure not the right size"
  148.     ENDC
  149.  
  150.         ;Note: nibbles $40 and $42 are not to be inverted
  151.         dc.w    (0)&$f000,(0)&$f000    ; ec_Interrupt (no interrupts)
  152.         dc.w    (~0)&$f000,(~0)&$f000    ; ec_Reserved11
  153.         dc.w    (~0)&$f000,(~0)&$f000    ; ec_BaseAddress (write only)
  154.         dc.w    (~0)&$f000,(~0)&$f000    ; ec_Shutup (write only)
  155.         dc.w    (~0)&$f000,(~0)&$f000    ; ec_Reserved14
  156.         dc.w    (~0)&$f000,(~0)&$f000    ; ec_Reserved15
  157.         dc.w    (~0)&$f000,(~0)&$f000    ; ec_Reserved16
  158.         dc.w    (~0)&$f000,(~0)&$f000    ; ec_Reserved17
  159.         dc.w    (~0)&$f000,(~0)&$f000    ; ec_Reserved18
  160.         dc.w    (~0)&$f000,(~0)&$f000    ; ec_Reserved19
  161.         dc.w    (~0)&$f000,(~0)&$f000    ; ec_Reserved1a
  162.         dc.w    (~0)&$f000,(~0)&$f000    ; ec_Reserved1b
  163.         dc.w    (~0)&$f000,(~0)&$f000    ; ec_Reserved1c
  164.         dc.w    (~0)&$f000,(~0)&$f000    ; ec_Reserved1d
  165.         dc.w    (~0)&$f000,(~0)&$f000    ; ec_Reserved1e
  166.         dc.w    (~0)&$f000,(~0)&$f000    ; ec_Reserved1f
  167.  
  168.     IFNE    *-RomStart-$80
  169.     FAIL    "Expansion Control structure not the right size"
  170.     ENDC
  171.  
  172.     ENDC    ;ROMINFO
  173.  
  174. *******  DiagStart  **************************************************
  175. DiagStart:  ; This is the DiagArea structure whose relative offset from
  176.             ; your board base appears as the Init Diag vector in your
  177.             ; autoconfig ID information.  This structure is designed
  178.             ; to use all relative pointers (no patching needed).
  179.             dc.b    DAC_WORDWIDE+DAC_CONFIGTIME    ; da_Config
  180.             dc.b    0                              ; da_Flags
  181.             dc.w    EndCopy-DiagStart              ; da_Size
  182.             dc.w    DiagEntry-DiagStart            ; da_DiagPoint
  183.             dc.w    BootEntry-DiagStart            ; da_BootPoint
  184.             dc.w    DevName-DiagStart              ; da_Name
  185.             dc.w    0                              ; da_Reserved01
  186.             dc.w    0                              ; da_Reserved02
  187.  
  188. *******  Resident Structure  *****************************************
  189. Romtag:
  190.             dc.w    RTC_MATCHWORD      ; UWORD RT_MATCHWORD
  191. rt_Match:   dc.l    Romtag-DiagStart   ; APTR  RT_MATCHTAG
  192. rt_End:     dc.l    EndCopy-DiagStart  ; APTR  RT_ENDSKIP
  193.             dc.b    RTW_COLDSTART      ; UBYTE RT_FLAGS
  194.             dc.b    VERSION            ; UBYTE RT_VERSION
  195.             dc.b    NT_DEVICE          ; UBYTE RT_TYPE
  196.             dc.b    20                 ; BYTE  RT_PRI
  197. rt_Name:    dc.l    DevName-DiagStart  ; APTR  RT_NAME
  198. rt_Id:      dc.l    IdString-DiagStart ; APTR  RT_IDSTRING
  199. rt_Init:    dc.l    Init-RomStart      ; APTR  RT_INIT
  200.  
  201.  
  202. ******* Strings referenced in Diag Copy area  ************************
  203. DevName:    dc.b    'abc.device',0                      ; Name string
  204. IdString    dc.b    'abc ',48+VERSION,'.',48+REVISION   ; Id string
  205.   
  206. DosName:    dc.b    'dos.library',0                ; DOS library name
  207.  
  208. DosDevName: dc.b    'ABC',0        ; dos device name for MakeDosNode()
  209.                                    ;   (dos device will be ABC:)
  210.  
  211.             ds.w    0              ; word align
  212.  
  213. *******  DiagEntry  **************************************************
  214. **********************************************************************
  215. *
  216. *   success = DiagEntry(BoardBase,DiagCopy, configDev)
  217. *   d0                  a0         a2                  a3
  218. *
  219. *   Called by expansion architecture to relocate any pointers
  220. *   in the copied diagnostic area.   We will patch the romtag.
  221. *   If you have pre-coded your MakeDosNode packet, BootNode, 
  222. *   or device initialization structures, they would also need
  223. *   to be within this copy area, and patched by this routine.
  224. *
  225. **********************************************************************
  226.  
  227. DiagEntry:
  228.             lea      patchTable-RomStart(a0),a1   ; find patch table
  229.             adda.l   #ROMOFFS,a1                  ; adjusting for ROMOFFS
  230.  
  231. * Patch relative pointers to labels within DiagCopy area
  232. * by adding Diag RAM copy address.  These pointers were coded as
  233. * long relative offsets from base of the DiagArea structure.
  234. * 
  235. dpatches:
  236.             move.l   a2,d1           ;d1=base of ram Diag copy
  237. dloop:
  238.             move.w   (a1)+,d0        ;d0=word offs. into Diag needing patch
  239.             bmi.s    bpatches        ;-1 is end of word patch offset table
  240.             add.l    d1,0(a2,d0.w)   ;add DiagCopy addr to coded rel. offset
  241.             bra.s    dloop
  242.  
  243. * Patches relative pointers to labels within the ROM by adding
  244. * the board base address + ROMOFFS.  These pointers were coded as
  245. * long relative offsets from RomStart.
  246. bpatches:
  247.             move.l   a0,d1           ;d1 = board base address
  248.             add.l    #ROMOFFS,d1     ;add offset to where your ROMs are
  249. rloop:
  250.             move.w   (a1)+,d0        ;d0=word offs. into Diag needing patch
  251.             bmi.s   endpatches       ;-1 is end of patch offset table
  252.             add.l   d1,0(a2,d0.w)    ;add ROM address to coded relative offset
  253.             bra.s   rloop
  254.  
  255. endpatches:
  256.             moveq.l #1,d0           ; indicate "success"
  257.             rts
  258.  
  259.  
  260. *******  BootEntry  **************************************************
  261. **********************************************************************
  262.  
  263. BootEntry:  lea     DosName(PC),a1          ; 'dos.library',0
  264.             jsr     _LVOFindResident(a6)    ; find the DOS resident tag
  265.             move.l  d0,a0                   ; in order to bootstrap
  266.             move.l  RT_INIT(A0),a0          ; set vector to DOS INIT
  267.             jsr     (a0)                    ; and initialize DOS
  268.             rts
  269.  
  270. *
  271. * End of the Diag copy area which is copied to RAM
  272. *
  273. EndCopy:
  274. *************************************************************************
  275.  
  276. *************************************************************************
  277. *
  278. *   Beginning of rom driver code and data that is accessed only in
  279. *   the rom space.  This must all be position-independent.
  280. *
  281.  
  282. patchTable:
  283. * Word offsets into Diag area where pointers need Diag copy address added
  284.             dc.w   rt_Match-DiagStart
  285.             dc.w   rt_End-DiagStart
  286.             dc.w   rt_Name-DiagStart
  287.             dc.w   rt_Id-DiagStart
  288.             dc.w   -1
  289.  
  290. * Word offsets into Diag area where pointers need boardbase+ROMOFFS added
  291.             dc.w   rt_Init-DiagStart
  292.             dc.w   -1
  293.  
  294. *******  Romtag InitEntry  **********************************************
  295. *************************************************************************
  296.  
  297. Init:       ; After Diag patching, our romtag will point to this 
  298.             ; routine in ROM so that it can be called at Resident
  299.             ; initialization time.
  300.             ; This routine will be similar to a normal expansion device
  301.             ; initialization routine, but will MakeDosNode then set up a
  302.             ; BootNode, and Enqueue() on eb_MountList. 
  303.             ;
  304.             rts
  305.  
  306.             ; Rest of your position-independent device code goes here.
  307.  
  308.             END
  309.